QT       += core gui network

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app

CONFIG += c++17
# Add /utf-8 flag only for MSVC builds to enforce UTF-8 encoding
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# For Windows crash dump generation and MessageBox functions (only for MSVC)
win32-msvc {
    LIBS += -lDbgHelp -luser32
}

# Include paths
INCLUDEPATH += $$PWD/Presenter/Inc
INCLUDEPATH += ../WheelMeasureConfig/Inc

INCLUDEPATH += ../../../VrNets/TCPClient/Inc
INCLUDEPATH += ../../../VrUtils/Inc
INCLUDEPATH += ../../../Device/VrEyeDevice/Inc
INCLUDEPATH += ../../../VrCommon/Inc
INCLUDEPATH += ../../../AppUtils/UICommon/Inc
INCLUDEPATH += ../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += ../../../AppUtils/AppCommon/Inc

INCLUDEPATH += ../../../SDK/Device/VzNLSDK/Inc
INCLUDEPATH += ../../../AppAlgo/wheelArchHeigthMeasure/Inc

# Link libraries
win32:CONFIG(debug, debug|release) {
    LIBS += -L../WheelMeasureConfig/debug           -lWheelMeasureConfig
    LIBS += -L../../../VrNets/debug                 -lVrTcpClient
    LIBS += -L../../../VrUtils/debug                -lVrUtils
    LIBS += -L../../../Device/VrEyeDevice/debug     -lVrEyeDevice
    LIBS += -L../../../AppUtils/UICommon/debug      -lUICommon
    LIBS += -L../../../AppUtils/CloudUtils/debug    -lCloudUtils
    LIBS += -L../../../AppUtils/AppCommon/debug     -lAppCommon
    LIBS += -L../../../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../../../VrNets/debug                 -lVrModbus

    # VzNLSDK
    LIBS += -L../../../SDK/Device/VzNLSDK/Windows/x64/Debug -lVzKerneld
} else:win32:CONFIG(release, debug|release) {
    LIBS += -L../WheelMeasureConfig/release           -lWheelMeasureConfig
    LIBS += -L../../../VrNets/release                 -lVrTcpClient
    LIBS += -L../../../VrUtils/release                -lVrUtils
    LIBS += -L../../../Device/VrEyeDevice/release     -lVrEyeDevice
    LIBS += -L../../../AppUtils/UICommon/release      -lUICommon
    LIBS += -L../../../AppUtils/CloudUtils/release    -lCloudUtils
    LIBS += -L../../../AppUtils/AppCommon/release     -lAppCommon
    LIBS += -L../../../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../../../VrNets/release                 -lVrModbus

    # VzNLSDK
    LIBS += -L../../../Device/VrEyeDevice/release    -lVrEyeDevice
}else:unix:!macx {
    # 注意：静态库链接顺序很重要，被依赖的库必须放在后面
    LIBS += -L../WheelMeasureConfig          -lWheelMeasureConfig
    LIBS += -L../../../AppUtils/AppCommon    -lAppCommon
    LIBS += -L../../../AppUtils/UICommon     -lUICommon
    LIBS += -L../../../AppUtils/CloudUtils   -lCloudUtils
    LIBS += -L../../../Device/VrEyeDevice    -lVrEyeDevice
    LIBS += -L../../../VrNets                -lVrTcpClient
    LIBS += -L../../../VrUtils               -lVrUtils
    LIBS += -L../../../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../../../VrNets                 -lVrModbus

    LIBS += -lrt
    QMAKE_CXXFLAGS += -fPIC
}

# 设置应用程序图标
RC_ICONS = resource/logo.ico

SOURCES += \
    dialogalgoarg.cpp \
    dialogcamera.cpp \
    dialogcameralevel.cpp \
    main.cpp \
    mainwindow.cpp \
    widgets/DeviceStatusWidget.cpp \
    widgets/ImageGridWidget.cpp \
    widgets/MeasureResultListWidget.cpp \
    Presenter/Src/WheelMeasurePresenter.cpp

HEADERS += \
    IWheelMeasureStatus.h \
    Version.h \
    dialogalgoarg.h \
    dialogcamera.h \
    dialogcameralevel.h \
    mainwindow.h \
    widgets/DeviceStatusWidget.h \
    widgets/ImageGridWidget.h \
    widgets/MeasureResultListWidget.h \
    Presenter/Inc/WheelMeasurePresenter.h

FORMS += \
    dialogalgoarg.ui \
    dialogcamera.ui \
    dialogcameralevel.ui \
    mainwindow.ui

RESOURCES += \
    resources.qrc \
    ../../../AppUtils/UICommon/common_resources.qrc

INCLUDEPATH += ../../../SDK/Device/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/Device/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics

    # wheelArchHeigthMeasure SDK
    LIBS += -L$$PWD/../../../AppAlgo/wheelArchHeigthMeasure/Windows/x64/Release
    LIBS += -lwheelArchHeigthMeasure -lbaseAlgorithm

    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd

    # wheelArchHeigthMeasure SDK
    LIBS += -L$$PWD/../../../AppAlgo/wheelArchHeigthMeasure/Windows/x64/Debug
    LIBS += -lwheelArchHeigthMeasure -lbaseAlgorithm

    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics

    # wheelArchHeigthMeasure SDK
    LIBS += -L$$PWD/../../../AppAlgo/wheelArchHeigthMeasure/Arm/aarch64
    LIBS += -lwheelArchHeigthMeasure -lbaseAlgorithm

    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target