# Qt 5 兼容：QOpenGLWidget 在 widgets 模块中
QT += core gui widgets opengl

CONFIG += c++17
CONFIG -= app_bundle

# Windows平台UTF-8编码支持
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CXXFLAGS += /bigobj
}

TARGET = CloudView
TEMPLATE = app

# 项目目录
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../SDK/Device/VzNLSDK/Inc
INCLUDEPATH += $$PWD/../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../VrCommon/Inc

# 头文件
HEADERS += \
    Inc/CloudViewMainWindow.h \
    Inc/PointCloudGLWidget.h \
    Inc/PointCloudConverter.h

# 源文件
SOURCES += \
    main.cpp \
    Src/CloudViewMainWindow.cpp \
    Src/PointCloudGLWidget.cpp \
    Src/PointCloudConverter.cpp

# 资源文件
RESOURCES += resource/resource.qrc

# Windows 应用图标
RC_ICONS = resource/logo.ico

# Windows平台库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L../../AppUtils/CloudUtils/release -lCloudUtils
    LIBS += -L../../VrUtils/release -lVrUtils
    LIBS += -L../../VrCommon/release -lVrCommon
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L../../AppUtils/CloudUtils/debug -lCloudUtils
    LIBS += -L../../VrUtils/debug -lVrUtils
    LIBS += -L../../VrCommon/debug -lVrCommon
}

# Windows系统库
win32 {
    LIBS += -lAdvapi32
    LIBS += -lopengl32
    LIBS += -lglu32
}


DEFINES += _USE_MATH_DEFINES

# Default rules for deployment
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target