# CalibView - 手眼标定测试工具
QT += core gui widgets

CONFIG += c++17
CONFIG -= app_bundle

# Windows平台UTF-8编码支持
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CXXFLAGS += /bigobj
}

TARGET = CalibView
TEMPLATE = app

# 项目目录
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/../../Module/HandEyeCalib/Inc
INCLUDEPATH += $$PWD/../../Module/HandEyeCalib/_Inc
INCLUDEPATH += $$PWD/../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../SDK/eigen-3.3.9

# 头文件
HEADERS += \
    Inc/CalibViewMainWindow.h \
    Inc/CalibDataWidget.h \
    Inc/CalibResultWidget.h

# 源文件
SOURCES += \
    main.cpp \
    Src/CalibViewMainWindow.cpp \
    Src/CalibDataWidget.cpp \
    Src/CalibResultWidget.cpp

# 资源文件
RESOURCES += resource/resource.qrc

# Windows 应用图标
RC_ICONS = resource/logo.ico

# Windows平台库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L../../Module/HandEyeCalib/release -lHandEyeCalib
    LIBS += -L../../VrCommon/release -lVrCommon
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L../../Module/HandEyeCalib/debug -lHandEyeCalibd
    LIBS += -L../../VrCommon/debug -lVrCommon
}

# Unix平台库链接
unix {
    LIBS += -L../../Module/HandEyeCalib -lHandEyeCalib
    LIBS += -L../../VrCommon -lVrCommon
    QMAKE_CXXFLAGS += -fPIC
}

# Windows系统库
win32 {
    LIBS += -lAdvapi32
}

DEFINES += _USE_MATH_DEFINES

# Default rules for deployment
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target