# BinocularMarkReceiver.pro

QT       -= core gui network

TARGET = BinocularMarkReceiver
TEMPLATE = lib
CONFIG += c++17 

win32 {
    CONFIG += shared
} 

unix {
    CONFIG +=  staticlib
}

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE
DEFINES += BINOCULARMARKRECEIVER_LIBRARY

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# 包含路径
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/_Inc
INCLUDEPATH += $$PWD/../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../VrUtils/jsoncpp
INCLUDEPATH += $$PWD/../../VrNets/TCPClient/Inc

# 头文件
HEADERS += \
    Inc/IBinocularMarkReceiver.h \
    _Inc/BinocularMarkReceiver.h

# 源文件
SOURCES += \
    Src/BinocularMarkReceiver.cpp

# 库链接
win32 {
    CONFIG(debug, debug|release) {
        LIBS += -L../../VrNets/debug  -lVrTCPClient
        LIBS += -L../../VrUtils/debug -lVrUtils
    } else {
        LIBS += -L../../VrNets/release -lVrTCPClient
        LIBS += -L../../VrUtils/release -lVrUtils
    }
}

unix {
    LIBS += -L../../VrNets    -lVrTcpClient
    LIBS += -L../../VrUtils   -lVrUtils
    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target