# EpicEyeDevice.pro
# EpicEye 3D相机设备封装库

CONFIG -= qt

TEMPLATE = lib
CONFIG += staticlib
DEFINES += EPICEYEDEVICE_LIBRARY

CONFIG += c++17

# 支持 UTF-8 编码
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CFLAGS += /utf-8
}

# 头文件路径
INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc
INCLUDEPATH += $$PWD/../../VrCommon/Inc

# 源文件
SOURCES += \
    Src/EpicEyeDevice.cpp

# 头文件
HEADERS += \
    Inc/IEpicEyeDevice.h \
    Inc/EpicEyeDevice_global.h \
    _Inc/EpicEyeDevice.h

# EpicEye SDK 头文件路径
INCLUDEPATH += $$PWD/../../SDK/EpicEye/include
INCLUDEPATH += $$PWD/../../SDK/EpicEye/thirdparty

# EpicEye SDK 源文件（直接编译进来）
SOURCES += \
    $$PWD/../../SDK/EpicEye/src/epiceye.cpp

# Windows 系统库依赖
win32 {
    LIBS += -lws2_32
    LIBS += -lAdvapi32
    LIBS += -lWinhttp
}

# Unix/Linux 平台设置
unix:!macx {
    message("build EpicEyeDevice for unix")

    # 生成位置无关代码
    QMAKE_CXXFLAGS += -fPIC

    # 添加系统库依赖
    LIBS += -ldl -lpthread -lrt

    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target