# IKapDevice.pro
# IKap 相机设备封装库

CONFIG -= qt

TEMPLATE = lib
CONFIG += staticlib
DEFINES += IKAPDEVICE_LIBRARY

CONFIG += c++17

# 支持 UTF-8 编码
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CFLAGS += /utf-8
}

# 头文件路径
INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc

# 源文件
SOURCES += \
    Src/IKapDevice.cpp

# 头文件
HEADERS += \
    Inc/IIKapDevice.h \
    Inc/IKapDevice_global.h \
    _Inc/IKapDevice.h

# IKapLibrary SDK 头文件路径
win32 {
    INCLUDEPATH += $$PWD/../../SDK/IKapLibrary/Windows/Include
}
unix:!macx {
    INCLUDEPATH += $$PWD/../../SDK/IKapLibrary/aarch/Include
}

# IKapLibrary SDK 库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../SDK/IKapLibrary/Windows/Lib/x64
    LIBS += -lIKapC
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../SDK/IKapLibrary/Windows/Lib/x64
    LIBS += -lIKapC
}
else:unix:!macx: {
    message("build IKapDevice for unix")
    LIBS += -L$$PWD/../../SDK/IKapLibrary/aarch/Lib
    LIBS += -lIKapC
    # 添加系统库依赖
    LIBS += -ldl -lpthread -lrt
}

# Windows 系统库依赖
win32 {
    LIBS += -lws2_32
    LIBS += -lAdvapi32
}

# Unix/Linux 平台设置
unix {
    # 生成位置无关代码
    QMAKE_CXXFLAGS += -fPIC
    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target