# HikDevice.pro
# 海康相机设备封装库

TEMPLATE = lib
CONFIG += staticlib
DEFINES += HIKDEVICE_LIBRARY

CONFIG += c++17

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    # 禁用第三方SDK（如HCNetSDK）的编码警告
    QMAKE_CXXFLAGS += /wd4828
}

# 禁用 Qt (纯 C++ 库)
# CONFIG -= qt

INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc
INCLUDEPATH += ../../VrCommon/Inc

SOURCES += \
    Src/HikDevice.cpp

HEADERS += \
    Inc/IHikDevice.h \
    Inc/HikDevice_global.h \
    _Inc/HikDevice.h

# VrUtils 日志依赖
INCLUDEPATH += $$PWD/../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../VrUtils/ini
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../VrUtils/debug -lVrUtils
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../VrUtils/release -lVrUtils
}else:unix:!macx {
    LIBS += -L../../VrUtils -lVrUtils
}

# HCNetSDK - 海康威视SDK
win32 {
    INCLUDEPATH += $$PWD/../../SDK/Device/HCNetSDK/Windows/Inc

    CONFIG(release, debug|release): {
        LIBS += -L$$PWD/../../SDK/Device/HCNetSDK/Windows/x64
        LIBS += -lHCNetSDK -lHCCore -lPlayCtrl
    }
    else:CONFIG(debug, debug|release): {
        LIBS += -L$$PWD/../../SDK/Device/HCNetSDK/Windows/x64
        LIBS += -lHCNetSDK -lHCCore -lPlayCtrl
    }

    # Windows 网络库
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}
else:unix:!macx {
    INCLUDEPATH += $$PWD/../../SDK/Device/HCNetSDK/Arm64/inc
    LIBS += -L$$PWD/../../SDK/Device/HCNetSDK/Arm64/lib
    LIBS += -lhcnetsdk -lHCCore -lPlayCtrl
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
}
!isEmpty(target.path): INSTALLS += target