# BagThreadPositionApp.pro

QT       += core gui network serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17 console

# 项目名称
TARGET = BagThreadPositionApp

# 模板类型
TEMPLATE = app

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc

INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../BagThreadPositionConfig/Inc
INCLUDEPATH += $$PWD/../../../Device/GlLineLaserDevice/Inc
INCLUDEPATH += $$PWD/../../../Device/VrEyeDevice/Inc

INCLUDEPATH += $$PWD/../../../Module/ModbusTCPServer/Inc
INCLUDEPATH += $$PWD/../../../Module/ModbusTCPClient/Inc

INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UICommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc

# 源文件
SOURCES += \
    Presenter/Src/ConfigManager.cpp \
    Presenter/Src/BagThreadPositionPresenter.cpp \
    Presenter/Src/DetectPresenter.cpp \
    main.cpp \
    mainwindow.cpp \
    dialogalgoarg.cpp \
    dialogdeviceconfig.cpp \
    resultitem.cpp

# 头文件
HEADERS += \
    Presenter/Inc/ConfigManager.h \
    Presenter/Inc/BagThreadPositionPresenter.h \
    Presenter/Inc/DetectPresenter.h \
    IYBagThreadPositionStatus.h \
    mainwindow.h \
    dialogalgoarg.h \
    dialogdeviceconfig.h \
    resultitem.h \
    Version.h

# UI文件
FORMS += \
    mainwindow.ui \
    dialogalgoarg.ui \
    dialogdeviceconfig.ui \
    resultitem.ui

# 资源文件
RESOURCES += \
    resources.qrc \
    ../../../AppUtils/UICommon/common_resources.qrc

# Windows任务栏图标配置
win32 {
    RC_ICONS = resource/logo.ico
}

win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../VrUtils/debug                    -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/debug        -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/debug          -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/debug         -lAppCommon
    LIBS += -L../BagThreadPositionConfig/debug          -lBagThreadPositionConfig
    LIBS += -L../../../Device/VrEyeDevice/debug         -lVrEyeDevice
    LIBS += -L../../../Device/GlLineLaserDevice/debug   -lGlLineLaserDevice
    LIBS += -L../../../Module/ModbusTCPServer/debug     -lModbusTCPServer
    LIBS += -L../../../Module/ModbusTCPClient/debug     -lModbusTCPClient
    LIBS += -L../../../VrNets/debug                     -lVrModbus
    LIBS += -L../../../Module/ShareMem/debug            -lShareMem

}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../VrUtils/release                  -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/release      -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/release        -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/release       -lAppCommon
    LIBS += -L../BagThreadPositionConfig/release        -lBagThreadPositionConfig
    LIBS += -L../../../Device/VrEyeDevice/release       -lVrEyeDevice
    LIBS += -L../../../Device/GlLineLaserDevice/release -lGlLineLaserDevice
    LIBS += -L../../../Module/ModbusTCPServer/release   -lModbusTCPServer
    LIBS += -L../../../Module/ModbusTCPClient/release   -lModbusTCPClient
    LIBS += -L../../../VrNets/release                   -lVrModbus
    LIBS += -L../../../Module/ShareMem/release          -lShareMem
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低（被依赖的库放在后面）
    LIBS += -L../BagThreadPositionConfig            -lBagThreadPositionConfig
    LIBS += -L../../../AppUtils/UICommon            -lUICommon
    LIBS += -L../../../AppUtils/AppCommon           -lAppCommon
    LIBS += -L../../../AppUtils/CloudUtils          -lCloudUtils
    LIBS += -L../../../Device/VrEyeDevice           -lVrEyeDevice
    LIBS += -L../../../Device/GlLineLaserDevice     -lGlLineLaserDevice
    LIBS += -L../../../Module/ModbusTCPServer       -lModbusTCPServer
    LIBS += -L../../../Module/ModbusTCPClient       -lModbusTCPClient
    LIBS += -L../../../VrNets                       -lVrModbus
    LIBS += -L../../../Module/ShareMem              -lShareMem
    LIBS += -L../../../VrUtils                      -lVrUtils

    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

# VzNLSDK 头文件（用于数据类型定义）
INCLUDEPATH += ../../../SDK/Device/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/Device/VzNLSDK/Inc

# gl_linelaser_sdk 头文件和库
INCLUDEPATH += ../../../SDK/Device/gl_linelaser_sdk/include

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
    # gl_linelaser_sdk
    LIBS += -L$$PWD/../../../SDK/Device/gl_linelaser_sdk/x64 
    LIBS += -lgl_linelaser_sdk
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
    # gl_linelaser_sdk
    LIBS += -L$$PWD/../../../SDK/Device/gl_linelaser_sdk/x64
    LIBS += -lgl_linelaser_sdk
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
    
    # gl_linelaser_sdk for Linux aarch64
    LIBS += -L$$PWD/../../../SDK/Device/gl_linelaser_sdk/aarch64_linux -lgl_linelaser_sdk
}


# 包裹拆线位置定位算法
INCLUDEPATH += ../../../AppAlgo/bagThreadPositioning/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../AppAlgo/bagThreadPositioning/Windows/x64/Release -lbagThreadPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../AppAlgo/bagThreadPositioning/Windows/x64/Debug -lbagThreadPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../AppAlgo/bagThreadPositioning/Arm/aarch64 -lbagThreadPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target

DISTFILES += \
    Version.md