GrabBag/App/BinocularMark/BinocularMarkApp/BinocularMarkApp.pro

QT       += core
QT       += network
QT       += gui
QT       += xml

TEMPLATE = app

CONFIG += c++11 console
CONFIG -= app_bundle

# Add /utf-8 flag only for MSVC builds to enforce UTF-8 encoding
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

# 头文件路径
INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc
INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc
INCLUDEPATH += $$PWD/../../../Device/GalaxyDevice/Inc

# SDK算法库路径
INCLUDEPATH += $$PWD/../../../AppAlgo/binocularMark/Inc
INCLUDEPATH += $$PWD/../../../SDK/Device/VzNLSDK/Inc
INCLUDEPATH += $$PWD/../../../SDK/Device/VzNLSDK/_Inc

# 源文件
SOURCES += \
    main.cpp \
    BinocularMarkPresenter.cpp \
    BinocularMarkTcpProtocol.cpp

HEADERS += \
    BinocularMarkPresenter.h \
    BinocularMarkTcpProtocol.h \
    Version.h

# Windows平台库链接
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../Device/GalaxyDevice/debug         -lGalaxyDevice
    LIBS += -L../../../VrNets/debug                      -lVrTCPServer
    LIBS += -L../../../VrUtils/debug                     -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon/debug          -lAppCommon
    # AppCommon 依赖
    LIBS += -L../../../Module/ModbusTCPServer/debug      -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/debug             -lShareMem
    LIBS += -L../../../VrNets/debug                      -lVrModbus
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../Device/GalaxyDevice/release       -lGalaxyDevice
    LIBS += -L../../../VrNets/release                    -lVrTCPServer
    LIBS += -L../../../VrUtils/release                   -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon/release        -lAppCommon
    # AppCommon 依赖
    LIBS += -L../../../Module/ModbusTCPServer/release    -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/release           -lShareMem
    LIBS += -L../../../VrNets/release                    -lVrModbus
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    LIBS += -L../../../Device/GalaxyDevice               -lGalaxyDevice
    LIBS += -L../../../VrNets                            -lVrTCPServer
    LIBS += -L../../../VrUtils                           -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon                -lAppCommon
    # AppCommon 依赖
    LIBS += -L../../../Module/ModbusTCPServer            -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem                   -lShareMem
    LIBS += -L../../../VrNets                            -lVrModbus

    # Galaxy SDK 库（GalaxyDevice 的依赖）
    LIBS += -L$$PWD/../../../SDK/Device/Galaxy/aarch64/lib/armv8 -lgxiapi

    # 添加系统库依赖
    LIBS += -lpthread
}

# binocularMark算法库（使用OpenCV480）
win32:CONFIG(release, debug|release): {
    INCLUDEPATH += $$PWD/../../../SDK/OpenCV480/Windows/include
    LIBS += -L$$PWD/../../../SDK/OpenCV480/Windows/x64/Release -lopencv_world480
    LIBS += -L$$PWD/../../../SDK/Device/Galaxy/Windows/lib/x64
    LIBS += -L$$PWD/../../../SDK/Device/Galaxy/Windows/bin/Win64
    LIBS += -L$$PWD/../../../SDK/Device/GenICam/bin/Win64_x64

    # SDK算法库
    LIBS += -L$$PWD/../../../AppAlgo/binocularMark/Windows/Release
    LIBS += -lbinocularMarkCam -lbaseAlgorithm
}
else:win32:CONFIG(debug, debug|release): {
    INCLUDEPATH += $$PWD/../../../SDK/OpenCV480/Windows/include
    LIBS += -L$$PWD/../../../SDK/OpenCV480/Windows/x64/Debug -lopencv_world480d
    LIBS += -L$$PWD/../../../SDK/Device/Galaxy/Windows/lib/x64
    LIBS += -L$$PWD/../../../SDK/Device/Galaxy/Windows/bin/Win64
    LIBS += -L$$PWD/../../../SDK/Device/GenICam/bin/Win64_x64

    # SDK算法库
    LIBS += -L$$PWD/../../../AppAlgo/binocularMark/Windows/Debug
    LIBS += -lbinocularMarkCam -lbaseAlgorithm
}
else:unix:!macx: {
    INCLUDEPATH += $$PWD/../../../SDK/OpenCV480/Arm/aarch64/include/opencv4
    # OpenCV 4.8.0 - 必须先链接 OpenCV（被算法库依赖）
    # 使用 --no-as-needed 和 --copy-dt-needed-entries 确保传递依赖也被解析
    LIBS += -Wl,--no-as-needed,--copy-dt-needed-entries
    LIBS += -L$$PWD/../../../SDK/OpenCV480/Arm/aarch64/lib \
            -lopencv_aruco \
            -lopencv_objdetect \
            -lopencv_dnn \
            -lopencv_calib3d \
            -lopencv_features2d \
            -lopencv_flann \
            -lopencv_highgui \
            -lopencv_imgcodecs \
            -lopencv_photo \
            -lopencv_imgproc \
            -lopencv_core

    # SDK算法库（依赖上面的 OpenCV）
    LIBS += -L$$PWD/../../../AppAlgo/binocularMark/Arm/aarch64
    LIBS += -lbinocularMarkCam -lbaseAlgorithm

    LIBS += -Wl,--as-needed
}

# 添加libmodbus依赖
win32 {
    LIBS += Shell32.lib
}