GrabBag/App/TunnelChannel/TunnelChannelApp/TunnelChannelApp.pro

# TunnelChannelApp.pro

QT       += core gui network serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17

# 项目名称
TARGET = TunnelChannelApp

# 模板类型
TEMPLATE = app

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    # 禁用第三方SDK（如HCNetSDK）的编码警告
    QMAKE_CXXFLAGS += /wd4828
}

INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc

INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../TunnelChannelConfig/Inc
INCLUDEPATH += $$PWD/../../../Device/VrEyeDevice/Inc

INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc

INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UICommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc

# HikDevice 封装库
INCLUDEPATH += $$PWD/../../../Device/HikDevice/Inc

# 通道间距测量算法库
INCLUDEPATH += $$PWD/../../../AppAlgo/channelSpaceMeasure/Inc

# 源文件
SOURCES += \
    DialogAlgoConfig.cpp \
    Presenter/Src/ConfigManager.cpp \
    Presenter/Src/TunnelChannelPresenter.cpp \
    main.cpp \
    mainwindow.cpp

# 头文件
HEADERS += \
    DialogAlgoConfig.h \
    Presenter/Inc/ConfigManager.h \
    Presenter/Inc/TunnelChannelPresenter.h \
    IYTunnelChannelStatus.h \
    mainwindow.h \
    Version.h

# UI文件
FORMS += \
    dialogalgoconfig.ui \
    mainwindow.ui

# 资源文件
RESOURCES += \
    resources.qrc \
    ../../../AppUtils/UICommon/common_resources.qrc

# Windows任务栏图标配置
win32 {
    RC_ICONS = resource/logo.ico
}

win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../VrUtils/debug                -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/debug    -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/debug      -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/debug     -lAppCommon
    LIBS += -L../TunnelChannelConfig/debug              -lTunnelChannelConfig
    LIBS += -L../../../Device/VrEyeDevice/debug            -lVrEyeDevice
    LIBS += -L../../../Device/HikDevice/debug              -lHikDevice
    LIBS += -L../../../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/debug        -lShareMem
    LIBS += -L../../../VrNets/debug                 -lVrModbus
    LIBS += -L../../../VrNets/debug                 -lVrTcpServer
    # 通道间距测量算法库
    LIBS += -L$$PWD/../../../AppAlgo/channelSpaceMeasure/Windows/x64/Debug -lHC_channelSpaceMeasure -lbaseAlgorithm

}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../VrUtils/release              -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/release  -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/release     -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/release   -lAppCommon
    LIBS += -L../TunnelChannelConfig/release            -lTunnelChannelConfig
    LIBS += -L../../../Device/VrEyeDevice/release          -lVrEyeDevice
    LIBS += -L../../../Device/HikDevice/release            -lHikDevice
    LIBS += -L../../../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/release      -lShareMem
    LIBS += -L../../../VrNets/release               -lVrModbus
    LIBS += -L../../../VrNets/release               -lVrTcpServer
    # 通道间距测量算法库
    LIBS += -L$$PWD/../../../AppAlgo/channelSpaceMeasure/Windows/x64/Release -lHC_channelSpaceMeasure -lbaseAlgorithm

}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低（被依赖的库放在后面）
    LIBS += -L../TunnelChannelConfig              -lTunnelChannelConfig
    LIBS += -L../../../AppUtils/UICommon       -lUICommon
    LIBS += -L../../../AppUtils/AppCommon     -lAppCommon
    LIBS += -L../../../AppUtils/CloudUtils    -lCloudUtils
    LIBS += -L../../../Device/VrEyeDevice            -lVrEyeDevice
    LIBS += -L../../../Device/HikDevice              -lHikDevice
    LIBS += -L../../../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../../../VrNets                 -lVrModbus
    LIBS += -L../../../Module/ShareMem        -lShareMem
    LIBS += -L../../../VrNets                 -lVrTcpServer
    LIBS += -L../../../VrUtils                -lVrUtils
    # 通道间距测量算法库
    LIBS += -L$$PWD/../../../AppAlgo/channelSpaceMeasure/Arm/aarch64 -lchannelSpaceMeasure -lbaseAlgorithm

    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

# VzNLSDK - 3D相机SDK
INCLUDEPATH += ../../../SDK/Device/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/Device/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}

# HCNetSDK - 海康威视SDK
INCLUDEPATH += ../../../SDK/Device/HCNetSDK/Windows/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/HCNetSDK/Windows/x64
    LIBS += -lHCNetSDK -lHCCore -lPlayCtrl
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/HCNetSDK/Windows/x64
    LIBS += -lHCNetSDK -lHCCore -lPlayCtrl
}
else:unix:!macx: {
    INCLUDEPATH += ../../../SDK/Device/HCNetSDK/Arm64/inc
    LIBS += -L$$PWD/../../../SDK/Device/HCNetSDK/Arm64/lib
    # PlayCtrl 依赖 SuperRender 和 AudioRender
    LIBS += -lhcnetsdk -lHCCore -lPlayCtrl -lSuperRender -lAudioRender -lhpr
}

# OpenCV
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target