GrabBag/App/WorkpieceHole/WorkpieceHoleApp/WorkpieceHoleApp.pro

# WorkpieceHoleApp.pro

QT       += core gui network serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++11

# 项目名称
TARGET = WorkpieceHoleApp

# 模板类型
TEMPLATE = app

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc

INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../WorkpieceHoleConfig/Inc
INCLUDEPATH += $$PWD/../../../Device/VrEyeDevice/Inc

INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc

INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UICommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc
INCLUDEPATH += $$PWD/../../../Module/AuthModule/Inc

# 坐标变换库
INCLUDEPATH += $$PWD/../../../DataUtils/CoordinateTransform/Inc
# eigen 依赖
INCLUDEPATH += $$PWD/../../../SDK/eigen-3.3.9

#opencv
INCLUDEPATH += $$PWD/../../../SDK/OpenCV320/include


# ModbusTCP 客户端库（只包含导出接口目录，不包含内部 modbus 头文件）
INCLUDEPATH += $$PWD/../../../Module/ModbusTCPClient/Inc

# 源文件
SOURCES += \
    Presenter/Src/ConfigManager.cpp \
    Presenter/Src/WorkpieceHolePresenter.cpp \
    Presenter/Src/DetectPresenter.cpp \
    Presenter/Src/TCPServerProtocol.cpp \
    Presenter/Src/TCPServerMethods.cpp \
    Presenter/Src/PLCModbusClient.cpp \
    main.cpp \
    mainwindow.cpp \
    dialogalgoarg.cpp \
    resultitem.cpp

# 头文件
HEADERS += \
    Presenter/Inc/ConfigManager.h \
    Presenter/Inc/WorkpieceHolePresenter.h \
    Presenter/Inc/DetectPresenter.h \
    Presenter/Inc/TCPServerProtocol.h \
    Presenter/Inc/ProtocolCommon.h \
    Presenter/Inc/PLCModbusClient.h \
    IYWorkpieceHoleStatus.h \
    mainwindow.h \
    dialogalgoarg.h \
    resultitem.h \
    Version.h

# UI文件
FORMS += \
    mainwindow.ui \
    dialogalgoarg.ui \
    resultitem.ui

# 资源文件
RESOURCES += \
    resources.qrc \
    ../../../AppUtils/UICommon/common_resources.qrc

# Windows任务栏图标配置
win32 {
    RC_ICONS = resource/logo.ico
}

win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../VrUtils/debug                -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/debug   -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/debug      -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/debug    -lAppCommon
    LIBS += -L../../../Module/AuthModule/debug      -lAuthModule
    LIBS += -L../WorkpieceHoleConfig/debug              -lWorkpieceHoleConfig
    LIBS += -L../../../Device/VrEyeDevice/debug            -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../../../Module/ModbusTCPClient/debug -lModbusTCPClient
    LIBS += -L../../../Module/ShareMem/debug        -lShareMem
    LIBS += -L../../../VrNets/debug                 -lVrModbus
    LIBS += -L../../../VrNets/debug                 -lVrTcpServer
    LIBS += -L../../../DataUtils/CoordinateTransform/debug -lCoordinateTransformd

}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../VrUtils/release              -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/release  -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/release     -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/release   -lAppCommon
    LIBS += -L../../../Module/AuthModule/release    -lAuthModule
    LIBS += -L../WorkpieceHoleConfig/release            -lWorkpieceHoleConfig
    LIBS += -L../../../Device/VrEyeDevice/release          -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../../../Module/ModbusTCPClient/release -lModbusTCPClient
    LIBS += -L../../../Module/ShareMem/release      -lShareMem
    LIBS += -L../../../VrNets/release               -lVrModbus
    LIBS += -L../../../VrNets/release               -lVrTcpServer
    LIBS += -L../../../DataUtils/CoordinateTransform/release -lCoordinateTransform
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低（被依赖的库放在后面）
    LIBS += -L../WorkpieceHoleConfig              -lWorkpieceHoleConfig
    LIBS += -L../../../AppUtils/UICommon       -lUICommon
    LIBS += -L../../../AppUtils/AppCommon     -lAppCommon
    LIBS += -L../../../Module/AuthModule       -lAuthModule
    LIBS += -L../../../AppUtils/CloudUtils    -lCloudUtils
    LIBS += -L../../../Device/VrEyeDevice            -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../../../Module/ModbusTCPClient -lModbusTCPClient
    LIBS += -L../../../VrNets                 -lVrModbus
    LIBS += -L../../../Module/ShareMem        -lShareMem
    LIBS += -L../../../VrNets                 -lVrTcpServer
    LIBS += -L../../../VrUtils                -lVrUtils
    LIBS += -L../../../DataUtils/CoordinateTransform -lCoordinateTransform

    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../../../SDK/Device/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/Device/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/Device/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法 - 使用 workpieceHolePositioning 算法
INCLUDEPATH += ../../../AppAlgo/workpieceHolePositioning/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../AppAlgo/workpieceHolePositioning/Windows/x64/Release -lworkpieceHolePositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../AppAlgo/workpieceHolePositioning/Windows/x64/Debug -lworkpieceHolePositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../AppAlgo/workpieceHolePositioning/Arm/aarch64 -lworkpieceHolePositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target

DISTFILES += \
    Version.md