GrabBag/Device/VrEyeDevice/VrEyeDevice.pro

#CONFIG -= qt

TEMPLATE = lib
CONFIG += staticlib
DEFINES += VREYEDEVICE_LIBRARY

CONFIG += c++17

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc
INCLUDEPATH += ../../VrCommon/Inc


SOURCES += \
    Src/VrConvert.cpp \
    Src/VrEyeDevice.cpp \
    Src/VrEyeCommon.cpp

HEADERS += \
    Inc/IVrEyeDevice.h \
    Inc/VrConvert.h \
    Inc/VrEyeDevice_global.h \
    VrEyeDevice_global.h \
    _Inc/VrEyeCommon.h \
    _Inc/VrEyeDevice.h



INCLUDEPATH += $$PWD/../../SDK/eigen-3.3.9

#linux下的为unix ，windows下用的win32
INCLUDEPATH += $$PWD/../../SDK/VzNLSDK/_Inc
INCLUDEPATH += $$PWD/../../SDK/VzNLSDK/Inc
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    message("build unix")
    LIBS += -L$$PWD/../../SDK/VzNLSDK/Arm/aarch64
    # 强制链接所有符号，避免循环依赖问题
    LIBS += -Wl,--whole-archive
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics -lVzLog -lVzEyeSecurityLoader-shared
    LIBS += -Wl,--no-whole-archive
    LIBS += -ldl -lpthread -lrt
}

INCLUDEPATH += $$PWD/../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../VrUtils/ini
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../VrUtils/debug -lVrUtils
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../VrUtils/release -lVrUtils
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    LIBS += -L../../VrUtils -lVrUtils
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}



# Default rules for deployment.
unix {
    target.path = /usr/lib
}
!isEmpty(target.path): INSTALLS += target